PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
            SELECT $this ?birthEarliest ?deathLatest
            WHERE {
                $this martialis:birthEvent/martialis:earliestYear ?birthEarliest .
                $this martialis:deathEvent/martialis:latestYear ?deathLatest .
                FILTER(xsd:integer(STR(?birthEarliest)) > xsd:integer(STR(?deathLatest)))
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE { $this (martialis:hasSite/martialis:withinPlace)+ $this }
        

            PREFIX schema: <https://schema.org/>
            SELECT $this ?value
            WHERE {
                $this schema:sameAs ?value .
                ?other schema:sameAs ?value .
                FILTER(?other != $this)
                FILTER(REGEX(STR($this), "^https://martial\\.is/entity/[0-9A-HJKMNP-TV-Z]{26}$"))
                FILTER(REGEX(STR(?other), "^https://martial\\.is/entity/[0-9A-HJKMNP-TV-Z]{26}$"))
            }
        

            PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
            SELECT DISTINCT $this
            WHERE {
              $this <https://w3id.org/martialis/ontology#startYear> ?s .
              $this <https://w3id.org/martialis/ontology#endYear> ?e .
              FILTER (xsd:integer(STR(?e)) < xsd:integer(STR(?s)))
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:partOf+ $this .
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:specializationOf ?resource .
                ?resource martialis:specializationOf ?any .
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX schema: <https://schema.org/>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:specializationOf ?resource .
                { $this schema:url ?u . ?resource schema:url ?u }
                UNION { $this martialis:partOf ?c }
                UNION { $this schema:name ?n } UNION { $this martialis:sourceType ?t }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:specializationOf ?resource .
                FILTER NOT EXISTS { $this martialis:archiveDate ?d }
                FILTER NOT EXISTS { $this martialis:accessed ?a }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX schema: <https://schema.org/>
            SELECT DISTINCT $this
            WHERE {
                FILTER NOT EXISTS { $this martialis:specializationOf ?resource }
                FILTER (NOT EXISTS { $this schema:name ?n }
                        || NOT EXISTS { $this martialis:sourceType ?t })
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:hasInteraction ?i .
                FILTER NOT EXISTS { $this martialis:teacher ?t }
                FILTER NOT EXISTS { ?i martialis:interactionPlace ?p }
                FILTER NOT EXISTS { ?i martialis:atEvent ?e }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                ?state martialis:specializationOf $this .
                ?evidence martialis:basedOnSource $this .
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:sourceLocation ?loc ;
                      martialis:sourceLocatorLabel ?label .
                FILTER(?label IN ("page", "volume", "issue", "line", "paragraph",
                                  "folio", "note", "table", "figure", "verse",
                                  "section", "equation", "opus", "act", "column",
                                  "elocation", "supplement"))
                FILTER(REGEX(STR(?loc), "^\\s*[0-9]+\\s*-\\s*[0-9]+\\s*$"))
                BIND(xsd:integer(REPLACE(STR(?loc), "^\\s*([0-9]+)\\s*-.*$", "$1")) AS ?from)
                BIND(xsd:integer(REPLACE(STR(?loc), "^.*-\\s*([0-9]+)\\s*$", "$1")) AS ?to)
                FILTER(?from > ?to)
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:hasInteraction ?i .
                FILTER NOT EXISTS { $this martialis:teacher ?t }
                FILTER NOT EXISTS { ?i martialis:interactionPeriod/martialis:startYear ?y }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
            SELECT $this ?value
            WHERE {
                $this martialis:rankGrade ?value ; martialis:rankSystem ?rs .
                ?rs martialis:gradeScheme ?scheme .
                FILTER NOT EXISTS { ?value skos:inScheme ?scheme }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT $this ?value
            WHERE {
                $this martialis:rankGrade ?value ; martialis:rankSystem ?rs .
                FILTER NOT EXISTS { ?rs martialis:gradeScheme ?any }
            }
        

            SELECT DISTINCT $this
            WHERE {
                $this <https://w3id.org/martialis/ontology#identityCandidate> ?p .
                ?p ?link $this .
            }
        

            SELECT DISTINCT $this
            WHERE {
                $this <https://w3id.org/martialis/ontology#relatedStyle> ?s .
                ?s ?link $this .
            }
        

            SELECT DISTINCT $this
            WHERE {
                $this <https://w3id.org/martialis/ontology#relatedOrganization> ?o .
                ?o ?link $this .
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX affrel: <https://w3id.org/martialis/vocab/affiliation-relation/>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:affiliationRelation ?rel .
                ?s ?link $this .
                FILTER (?rel IN (affrel:derived_from, affrel:split_from, affrel:merged_from,
                                 affrel:replaces, affrel:renamed_from))
                FILTER NOT EXISTS { ?s a martialis:Organization }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX schema: <https://schema.org/>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:hasEvidence ?e .
                FILTER NOT EXISTS {
                    $this martialis:hasEvidence ?e2 .
                    FILTER NOT EXISTS {
                        { ?e2 martialis:basedOnSource/schema:url ?u2 } UNION { ?e2 schema:url ?u2 }
                        FILTER(CONTAINS(STR(?u2), "wikipedia.org"))
                    }
                }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
            SELECT DISTINCT $this
            WHERE {
                FILTER NOT EXISTS { $this martialis:teacher ?teacher }
                $this martialis:hasInteraction ?i .
                ?i martialis:interactionPlace ?place ;
                   martialis:interactionPeriod ?period .
                ?period martialis:startYear ?start .
                FILTER NOT EXISTS {
                    ?place martialis:hasInstructorRole ?role .
                    ?role martialis:instructorPeriod ?rperiod .
                    ?rperiod martialis:startYear ?rstart .
                    OPTIONAL { ?rperiod martialis:endYear ?rend }
                    FILTER(xsd:integer(STR(?rstart)) <= xsd:integer(STR(?start))
                           && (!BOUND(?rend) || xsd:integer(STR(?rend)) >= xsd:integer(STR(?start))))
                }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
            SELECT DISTINCT $this
            WHERE {
                ?person martialis:hasTeacherAssertion $this , ?named .
                FILTER NOT EXISTS { $this martialis:teacher ?none }
                ?named martialis:teacher ?teacher .
                OPTIONAL { $this martialis:assertedStyle ?style }
                OPTIONAL { ?named martialis:assertedStyle ?namedStyle }
                FILTER (!BOUND(?style) || !BOUND(?namedStyle) || ?style = ?namedStyle)
                $this martialis:hasInteraction ?i .
                ?named martialis:hasInteraction ?j .
                { ?i martialis:interactionPlace ?anchor . ?j martialis:interactionPlace ?anchor }
                UNION
                { ?i martialis:atEvent ?anchor . ?j martialis:atEvent ?anchor }
                ?i martialis:interactionPeriod/martialis:startYear ?start .
                OPTIONAL { ?i martialis:interactionPeriod/martialis:endYear ?end }
                OPTIONAL { ?j martialis:interactionPeriod/martialis:startYear ?namedStart }
                OPTIONAL { ?j martialis:interactionPeriod/martialis:endYear ?namedEnd }
                FILTER ((!BOUND(?namedStart) || xsd:integer(STR(?namedStart)) <= xsd:integer(STR(COALESCE(?end, ?start))))
                        && (!BOUND(?namedEnd) || xsd:integer(STR(?namedEnd)) >= xsd:integer(STR(?start))))
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX schema: <https://schema.org/>
            PREFIX eventclass: <https://w3id.org/martialis/vocab/event-classification/>
            PREFIX eventrole: <https://w3id.org/martialis/vocab/event-role/>
            SELECT DISTINCT $this
            WHERE {
                $this a martialis:Event ;
                       martialis:eventType ?type ;
                       schema:about ?s1 , ?s2 ;
                       martialis:hasParticipation ?p .
                ?p martialis:participationRole eventrole:instructor .
                FILTER (?type IN (eventclass:course, eventclass:seminar))
                FILTER (?s1 != ?s2)
                FILTER NOT EXISTS { ?p martialis:participationStyle ?st }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX schema: <https://schema.org/>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:transmissionDocument ?doc .
                ?doc martialis:hasContributor ?c .
                ?c martialis:contributorRole ?role .
                FILTER (?role IN ("author", "original-author", "container-author"))
                FILTER EXISTS {
                    { ?c schema:familyName ?f } UNION
                    { ?c schema:givenName ?g } UNION
                    { ?c schema:name ?n }
                }
                FILTER NOT EXISTS { ?c martialis:contributorPerson ?p }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX schema: <https://schema.org/>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:dateConferred ?date ;
                      martialis:hasConfidence ?conf .
                ?conf martialis:confidenceRationale ?rationale .
                FILTER(!CONTAINS(STR(?date), "~") && !CONTAINS(STR(?date), "?")
                       && !CONTAINS(STR(?date), "%") && !CONTAINS(STR(?date), "/")
                       && !CONTAINS(STR(?date), "["))
                FILTER(REGEX(STR(?rationale), "circa|approx|conflicting date|disput|uncertain date|probably (in|around)|before [0-9]{4}", "i"))
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:hasEvidence ?e .
                FILTER NOT EXISTS { $this martialis:hasEvidence/martialis:quotation ?q }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX schema: <https://schema.org/>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:hasEvidence ?e .
                FILTER NOT EXISTS {
                    $this martialis:hasEvidence ?e2 .
                    FILTER NOT EXISTS {
                        { ?e2 martialis:basedOnSource/schema:url ?u2 } UNION { ?e2 schema:url ?u2 }
                        FILTER(CONTAINS(STR(?u2), "wikipedia.org"))
                    }
                }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this a martialis:RankAssertion .
                FILTER NOT EXISTS { $this martialis:rankType ?t }
                FILTER NOT EXISTS { $this martialis:rankOrdinal ?o }
                FILTER NOT EXISTS { $this martialis:rankGrade ?g }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:dissolvedEvent ?d .
                FILTER NOT EXISTS { ?d martialis:dissolutionManner ?m }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX diss: <https://w3id.org/martialis/vocab/dissolution-manner/>
            PREFIX affrel: <https://w3id.org/martialis/vocab/affiliation-relation/>
            SELECT DISTINCT $this
            WHERE {
                {
                    $this martialis:dissolvedEvent/martialis:dissolutionManner diss:merged .
                    BIND(affrel:merged_from AS ?expectedRel)
                } UNION {
                    $this martialis:dissolvedEvent/martialis:dissolutionManner diss:superseded .
                    BIND(affrel:replaces AS ?expectedRel)
                } UNION {
                    $this martialis:dissolvedEvent/martialis:dissolutionManner diss:renamed .
                    BIND(affrel:renamed_from AS ?expectedRel)
                }
                FILTER NOT EXISTS {
                    ?successor martialis:hasAffiliationAssertion ?a .
                    ?a martialis:relatedOrganization $this ;
                       martialis:affiliationRelation ?expectedRel .
                }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX affrel: <https://w3id.org/martialis/vocab/affiliation-relation/>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:affiliationRelation ?rel ;
                      martialis:relatedOrganization ?predecessor .
                FILTER (?rel IN (affrel:merged_from, affrel:replaces, affrel:renamed_from))
                FILTER NOT EXISTS { ?predecessor martialis:dissolvedEvent ?d }
            }
        

            SELECT $this ?name
            WHERE {
                $this schema:alternateName ?name .
                FILTER(CONTAINS(STR(?name), ";"))
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                FILTER NOT EXISTS {
                    $this martialis:hasEvidence ?ev .
                    ?ev a martialis:SourceAssertionRelation .
                }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX schema: <https://schema.org/>
            SELECT DISTINCT $this
            WHERE {
                FILTER NOT EXISTS { $this schema:location ?loc }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:dissolvedEvent ?d ;
                      martialis:hasSite/martialis:sitePeriod ?p .
                ?p martialis:startYear ?s .
                FILTER NOT EXISTS { ?p martialis:endYear ?e }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:specializationOf?/martialis:sourceType "webpage" .
                FILTER NOT EXISTS { $this martialis:accessed ?a }
                FILTER NOT EXISTS { ?state martialis:specializationOf $this }
            }
        

            PREFIX schema: <https://schema.org/>
            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:specializationOf?/martialis:sourceType "webpage" .
                FILTER NOT EXISTS { $this schema:archivedAt ?a }
                FILTER NOT EXISTS { ?state martialis:specializationOf $this }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:sourceType ?type .
                FILTER (?type NOT IN ("website", "periodical", "collection", "book"))
                FILTER NOT EXISTS { $this martialis:partOf ?container }
                FILTER NOT EXISTS { $this martialis:specializationOf ?resource }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:partOf ?p1 .
                ?p1 martialis:partOf ?p2 .
                ?p2 martialis:partOf ?p3 .
                ?p3 martialis:partOf ?p4 .
            }
        

            PREFIX schema: <https://schema.org/>
            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:selfPublished ?asserted .
                OPTIONAL {
                    $this schema:publisher [ martialis:publisherOrg ?pubOrg ] ;
                          martialis:hasContributor [ martialis:contributorOrg ?pubOrg ] .
                    BIND(true AS ?derived)
                }
                FILTER (
                    (?asserted = true && !BOUND(?derived)
                        && EXISTS { $this schema:publisher/martialis:publisherOrg ?anyOrg }) ||
                    (?asserted = false && BOUND(?derived))
                )
            }
        

            PREFIX schema: <https://schema.org/>
            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this schema:publisher [ schema:name ?pubName ] .
                FILTER NOT EXISTS { $this martialis:partOf ?anyC }
                FILTER NOT EXISTS { $this martialis:specializationOf ?resource }
                ?container a martialis:Source ; schema:name ?contTitle .
                FILTER (?container != $this)
                FILTER EXISTS { ?anyItem martialis:partOf ?container }
                FILTER (CONTAINS(LCASE(?pubName), LCASE(?contTitle)))
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this ?container
            WHERE {
                $this martialis:basedOnSource ?container .
                ?item martialis:partOf ?container .
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX conflevel: <https://w3id.org/martialis/vocab/confidence-level/>
            PREFIX infotype: <https://w3id.org/martialis/vocab/information-type/>
            PREFIX evidencetype: <https://w3id.org/martialis/vocab/evidence-type/>
            PREFIX sdo: <https://schema.org/>
            SELECT $this WHERE {
                $this martialis:hasConfidence/martialis:confidenceLevel conflevel:confirmed .
                OPTIONAL {
                    SELECT $this (COUNT(DISTINCT ?src) AS ?n) WHERE {
                        $this (martialis:hasEvidence | martialis:hasInteraction/martialis:hasEvidence) ?ev .
                        ?ev martialis:supports true ; martialis:evidenceType evidencetype:direct .
                        OPTIONAL { ?ev martialis:basedOnSource ?bs } OPTIONAL { ?ev sdo:url ?u }
                        OPTIONAL { ?ev martialis:basedOnSource/sdo:url ?bsu }
                        BIND(IF(CONTAINS(STR(COALESCE(?bsu, ?u, "")), "wikipedia.org"), "wikipedia", COALESCE(?bs, ?u)) AS ?src)
                    } GROUP BY $this
                }
                FILTER(COALESCE(?n, 0) < 2)
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX conflevel: <https://w3id.org/martialis/vocab/confidence-level/>
            PREFIX evidencetype: <https://w3id.org/martialis/vocab/evidence-type/>
            SELECT $this WHERE {
                VALUES ?level { conflevel:probable conflevel:confirmed }
                $this martialis:hasConfidence/martialis:confidenceLevel ?level .
                FILTER NOT EXISTS {
                    $this (martialis:hasEvidence | martialis:hasInteraction/martialis:hasEvidence) ?ev .
                    ?ev martialis:supports true ; martialis:evidenceType evidencetype:direct .
                }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX conflevel: <https://w3id.org/martialis/vocab/confidence-level/>
            PREFIX evidencetype: <https://w3id.org/martialis/vocab/evidence-type/>
            SELECT $this WHERE {
                $this martialis:hasConfidence/martialis:confidenceLevel conflevel:refuted .
                FILTER NOT EXISTS {
                    VALUES ?type { evidencetype:direct evidencetype:indirect }
                    $this (martialis:hasEvidence | martialis:hasInteraction/martialis:hasEvidence) ?ev .
                    ?ev martialis:supports false ; martialis:evidenceType ?type .
                }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX conflevel: <https://w3id.org/martialis/vocab/confidence-level/>
            PREFIX sdo: <https://schema.org/>
            SELECT $this WHERE {
                $this a martialis:TraditionOnlyAssertion ;
                      martialis:hasConfidence/martialis:confidenceLevel conflevel:confirmed .
                FILTER NOT EXISTS {
                    $this (martialis:conferredBy | martialis:grantedBy) ?grantor ;
                          martialis:hasEvidence/martialis:basedOnSource/sdo:publisher/martialis:publisherOrg ?grantor .
                }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX stylerel: <https://w3id.org/martialis/vocab/style-relation/>
            SELECT DISTINCT $this
            WHERE {
                ?a ?link $this .
                $this martialis:relatedStyle ?b ;
                      martialis:styleRelationType stylerel:sibling_style_of .
                FILTER NOT EXISTS {
                    ?b ?back ?rev .
                    ?rev martialis:relatedStyle ?a ;
                         martialis:styleRelationType stylerel:sibling_style_of .
                }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                FILTER EXISTS { $this martialis:variantOf+ $this }
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
            SELECT DISTINCT $this
            WHERE {
                ?student ?link $this .
                $this martialis:teacher ?teacher .
                ?student martialis:birthEvent/martialis:latestYear ?studentLatest .
                ?teacher martialis:birthEvent/martialis:earliestYear ?teacherEarliest .
                FILTER(xsd:integer(STR(?teacherEarliest)) > xsd:integer(STR(?studentLatest)))
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
            SELECT DISTINCT $this
            WHERE {
                ?student ?link ?assertion .
                ?assertion martialis:hasInteraction $this ;
                           martialis:teacher ?teacher .
                $this martialis:interactionPeriod ?period .
                ?period martialis:startYear ?start .
                {
                    { ?student martialis:birthEvent/martialis:earliestYear ?bound .
                      BIND("lower" AS ?kind) }
                    UNION
                    { ?student martialis:deathEvent/martialis:latestYear ?bound .
                      BIND("upper" AS ?kind) }
                    UNION
                    { ?teacher martialis:birthEvent/martialis:earliestYear ?bound .
                      BIND("lower" AS ?kind) }
                    UNION
                    { ?teacher martialis:deathEvent/martialis:latestYear ?bound .
                      BIND("upper" AS ?kind) }
                }
                FILTER ( (?kind = "lower" && xsd:integer(STR(?start)) < xsd:integer(STR(?bound)))
                      || (?kind = "upper" && xsd:integer(STR(?start)) > xsd:integer(STR(?bound))) )
            }
        

            PREFIX martialis: <https://w3id.org/martialis/ontology#>
            SELECT DISTINCT $this
            WHERE {
                $this martialis:hasEvidence ?e .
                FILTER NOT EXISTS { $this martialis:hasEvidence/martialis:quotation ?q }
            }